巨集無反應

我問大X的做法下去用..測試 macro test 會有自動反應..但是接下去的外掛反而沒反應
以下是我的巨集指令(其實是從論壇抓下來做點地點的更改,幫我看看哪裡要改又該如何起動它!!)


macro test {
do c 111
}
automacro a {
        console /您現在已在遊戲中/
        exclusive 1
        call {
        if (@invamount(藍色魔力礦石) = 0) goto qk
        pause 3
        do look 4
        do deal no
        do chat create "中央2000石波3000古城5000犬妖6000請自行投幣" 2 0 4528
        #a-1 b-2 c-3 d-4 = 設定未完成請勿投幣
        pause 1
        do sit
        release all
        stop
        :qk
        do sit
        stop
        }
}
automacro b {
        console /(.*) ((.*)) 向您要求一個交易/
        run-once 1
        call {
        do deal
        pause 15
        #15秒內不動作取消交易
        do deal no
        }
}
automacro c {
        console /(.*) 加入物品以交易: (.*)/
        call {
        do deal no
        #加入物品取消交易
        }
}
automacro d {
        console /(.*) 加入 (.*) z 以交易/
        run-once 1
        call {
        $a = $.lastMatch2
        if ($a = 2,000) goto bb
        if ($a = 3,000) goto bb
        if ($a = 5,000) goto bb
        if ($a = 6,100) goto bb
        #$a = ".*" = 傳陣金額
        pause 1
        do deal no
        #當金額!=你販賣的金額取消交易
        stop
        :bb
        pause 1
        do deal
        pause 1
        do deal
        pause 10
        do deal no
        #輸入金額10秒內未完成交易者取消交易
        }
}
automacro f {
        console /您 獲得  (.*) zeny./
        run-once 1
        call {
        pause 1
        do chat leave
        $a = $.lastMatch1
        if ($a = 2,000) goto a1
        if ($a = 3,000) goto b2
        if ($a = 5,000) goto c3
        if ($a = 6,000) goto d4
        #$a = ".*" = 傳陣金額
        :a1
        call aa1
        #執行macro aa1
        stop
        :b2
        call bb2
        stop
        :c3
        call cc3
        stop
        :d4
        call dd4
     
        }
}
automacro e {
        console /交易已取消/
        call {
        release all
        }
}
macro aa1 {
        $aa1 = @invamount(藍色魔力礦石)
        #施放傳送之陣"前"的藍色魔力礦石數量
        $x = @arg("$.pos", 1)
        $y = @arg("$.pos", 2)
        $x0 = @eval($x - @rand(1,3))
        $y0 = @eval($y - @rand(1,3))
        do sl 27 $x0 $y0
        pause 1
        do warp prontera
        #a = 地圖名稱
        pause 1
        $aa2 = @invamount(藍色魔力礦石)
        #施放傳送之陣"後"的藍色魔力礦石數量
        if ($aa1 == $aa2) goto ax
        #當施放傳送之陣前後藍色魔力礦石相等判定傳送失敗跳至:ax
        do c [中央]請進~一路順風並祝您遊戲愉快
        call start
        stop
        :ax
        pause 1
        call axx
        #執行macro axx
}
macro axx {
        call aa1
        #執行macro aa1
}
macro bb2 {
        $aa1 = @invamount(藍色魔力礦石)
        #施放傳送之陣"前"的藍色魔力礦石數量
        $x = @arg("$.pos", 1)
        $y = @arg("$.pos", 2)
        $x0 = @eval($x - @rand(1,3))
        $y0 = @eval($y - @rand(1,3))
        do sl 27 $x0 $y0
        pause 1
        do warp ve_fild07
        #a = 地圖名稱
        pause 1
        $aa2 = @invamount(藍色魔力礦石)
        #施放傳送之陣"後"的藍色魔力礦石數量
        if ($aa1 == $aa2) goto ax
        #當施放傳送之陣前後藍色魔力礦石相等判定傳送失敗跳至:ax
        do c [石玻]請進~一路順風並祝您遊戲愉快
        call start
        stop
        :ax
        pause 1
        call bxx
}
macro bxx {
        call bb2
}
macro cc3 {
        $aa1 = @invamount(藍色魔力礦石)
        #施放傳送之陣"前"的藍色魔力礦石數量
        $x = @arg("$.pos", 1)
        $y = @arg("$.pos", 2)
        $x0 = @eval($x - @rand(1,3))
        $y0 = @eval($y - @rand(1,3))
        do sl 27 $x0 $y0
        pause 1
        do warp glast_01
        #a = 地圖名稱
        pause 1
        $aa2 = @invamount(藍色魔力礦石)
        #施放傳送之陣"後"的藍色魔力礦石數量
        if ($aa1 == $aa2) goto ax
        #當施放傳送之陣前後藍色魔力礦石相等判定傳送失敗跳至:ax
        do c [古城]請進~一路順風並祝您遊戲愉快
        call start
        stop
        :ax
        pause 1
        call cxx
}
macro cxx {
        call cc3
}
macro dd4 {
        $aa1 = @invamount(藍色魔力礦石)
        #施放傳送之陣"前"的藍色魔力礦石數量
        $x = @arg("$.pos", 1)
        $y = @arg("$.pos", 2)
        $x0 = @eval($x - @rand(1,3))
        $y0 = @eval($y - @rand(1,3))
        do sl 27 $x0 $y0
        pause 1
        do warp ra_fild05
        #a = 地圖名稱
        pause 1
        $aa2 = @invamount(藍色魔力礦石)
        #施放傳送之陣"後"的藍色魔力礦石數量
        if ($aa1 == $aa2) goto ax
        #當施放傳送之陣前後藍色魔力礦石相等判定傳送失敗跳至:ax
        do c [犬妖]請進~一路順風並祝您遊戲愉快
        call start
        stop
        :ax
        pause 1
        call dxx
}
macro bxx {
        call dd4
}
macro start {
        if (@invamount(藍色魔力礦石) == 0) goto qk
        pause 3
        do look 4
        do deal no
        do chat create "中央2000石波3000古城5000犬妖6000請自行投幣" 2 0 4528
        #a-1 b-2 c-3 d-4 = 聊天室名稱
        pause 1
        do sit
        release all
        stop
        :qk
        do sit
        stop
}

除了111有反應外..其它都無法動作..誰幫我看一下..

妳的外掛是顯示中文還是英文?
用automacro a來試試(以下2組分別測試看看哪組有反應
console /您現在已在遊戲中/
console /Your Coordinates/

技能顯示是中文

console /Your Coordinates/
使用這個是一進去就坐下


console /您現在已在遊戲中/
使用這個是一進去就站著沒反應

那麼你的外掛應該是英文顯示
至於一開始會坐下是因為外掛來不及偵測身上的藍石所導致
你必須先把console裡的觸發句子改成英文顯示的句子

那之後呢該怎麼處理@@????????????????

那個腳本你不適用,試試以下修改過了
automacro Start {
        console /Your Coordinates/
        exclusive 1
        call {
        pause 3
        do conf ignoreAll 1
        call Chat
        }
}
macro Chat {
        do sit
        do look 4
        if (@invamount(藍色魔力礦石) > 0) goto OK
        do chat create "石頭沒了○o○" 2 0 9527
        stop
        :OK
        do chat create "中央2000石波3000古城5000犬妖6000請自行投幣" 2 0 4528
        # 自行修改聊天室內容
        do deal no
        # 避免在使用傳陣到創聊天室之間有人點交易
        release Deala
}
automacro Deala {
        console /Requests a Deal/
        inventory "藍色魔力礦石" > 0
        run-once 1
        call {
        do deal
        pause 15
        do deal no
        }
}
automacro Dealb {
        console /added Item to Deal/
        call {
        do deal no
        }
}
automacro Dealc {
        console /added (.*) z to Deal/
        call {
        $a = $.lastMatch1
        if ($a = 2,000) goto OK
        if ($a = 3,000) goto OK
        if ($a = 5,000) goto OK
        if ($a = 6,000) goto OK
        # 自行修改金額
        do deal no
        stop
        :OK
        pause 1
        do deal
        pause 1
        do deal
        pause 10
        do deal no
        }
}
automacro Warp {
        console /You gained (.*) zeny/
        exclusive 1
        call {
        $b = @invamount(藍色魔力礦石)
        do chat leave
        :Top
        $x = @arg("$.pos", 1)
        $y = @arg("$.pos", 2)
        $x0 = @eval($x - @rand(1,3))
        $y0 = @eval($y - @rand(1,3))
        do sl 27 $x0 $y0
        pause 2
        if ($a == "2,000") goto A
        if ($a == "3,000") goto B
        if ($a == "5,000") goto C
        if ($a == "6,000") goto D
        # 傳送點一
        :A
        do warp prontera
        goto End
        # 傳送點二
        :B
        do warp ve_fild07
        goto End
        # 傳送點三
        :C
        do warp glast_01
        goto End
        # 傳送點四
        :D
        do warp ra_fild05
        goto End
        :End
        pause 3
        if ($b == @invamount(藍色魔力礦石)) goto Top
        # 使用傳陣藍礦未減少回到Top
        do c 你的地圖已開
        call Chat
        }
}
automacro Dealno {
        console /Deal Cancelled/
        call {
        release Deala
        }
}

樓主大大
妳的聊天室名稱沒超過原限制字數嗎?

回7樓....沒有..
回X大..你給我的可以使用了..但會出現2排紅字
Error in function 'deal' (deal a player)
There is no incoming/current deal to cancel

那是正常情況
主要是防止開聊天室前就有人點交易,導致外掛無法接受其他人的交易