X大又要麻煩你了(聚集問題)

請問一下自動換大鋁.大神的聚集該如何寫??
想要自動從倉庫領出小鋁小神~在換成大鋁大神
我點是記在斐揚0.0

這樣要怎麼設定??

外掛開啟後輸入macro start開始執行巨集
先換鋁原,換完換神原
macro start {
        lock talk2
        lock storage2
        release talk1
        release storage1
        $c = 250
        #身上最多放多少鋁原
        $d = 250
        #身上最多放多少神原
        do move 138 177 payon
}

automacro talk1 {
        location payon 138 177
        inventory "鋁原石" > 4
        exclusive 1
        run-once 1
        call {
        do talknpc 137 178 c r1 n
        release talk1
        }
}

automacro storage1 {
        location payon 138 177
        inventory "鋁原石" < 5
        exclusive 1
        run-once 1
        call {
        do move 170 226
        pause 1
        do talknpc 175 226 c r1 n
        pause 1
        $p = @invamount (鋁)
        if ($p = 0) goto one
        do storage add @inventory (鋁)
        :one
        pause 1
        do storage get @storage (鋁原石) @eval($c - @invamount (鋁原石))
        pause 1
        $a = @storamount (鋁原石)
        $b = @invamount (鋁原石)
        if ($a = 0) goto end1
        do storage close
        do move payon 138 177
        release storage1
        stop
        :end1
        if ($b < 5) goto end2
        do storage close
        do move payon 138 177
        release storage1
        stop
        :end2
        if ($b = 0) goto end3
        do storage add @inventory (鋁原石)
        :end3
        do storage close
        call change
        }
}


macro change {
        lock talk1
        lock storage1
        release talk2
        release storage2
        do move 138 177 payon
}

automacro talk2 {
        location payon 138 177
        inventory "神之金屬原石" > 4
        exclusive 1
        run-once 1
        call {
        do talknpc 137 178 c r0 n
        release talk2
        }
}

automacro storage2 {
        location payon 138 177
        inventory "神之金屬原石" < 5
        exclusive 1
        run-once 1
        call {
        do move 170 226
        pause 1
        do talknpc 175 226 c r1 n
        pause 1
        $p = @invamount (神之金屬)
        if ($p = 0) goto one
        do storage add @inventory (神之金屬)
        :one
        pause 1
        do storage get @storage (神之金屬原石) @eval($d - @invamount (神之金屬原石))
        pause 1
        $a = @storamount (神之金屬原石)
        $b = @invamount (神之金屬原石)
        if ($a = 0) goto end1
        do storage close
        do move payon 138 177
        release storage2
        stop
        :end1
        if ($b < 5) goto end2
        do storage close
        do move payon 138 177
        release storage2
        stop
        :end2
        if ($b = 0) goto end3
        do storage add @inventory (神之金屬原石)
        :end3
        do storage close
        log 換完收工
        do quit
        }
}

感謝X大還傳短訊回覆我~真是麻煩X大了
那在請問一下~身上小神小鋁沒了會在自動從倉庫領嗎??
還有換好的大神大鋁會再存進倉庫嗎??

會自動從倉庫提領,也會把換好的放進倉庫
你實際跑看看不就知道了