[已解決] 請問有大大能夠教我如何才能讓OK會自動發送訊息給我嗎?

有2支角色
先假定名稱為 A 與 B
而 A 為手動, B 為 OK 自動

情況1:
我想當有人發送密語給 B 的時候
B 會自動將該段訊息用密語發送給 A (包括發送人的名稱)
然後當 A 用密語回覆給 B 後 (例如回覆時以 回覆(發送人名稱): 為開頭的訊息)
B 會自動將該段訊息回覆給發送人

情況2:
當 B 的公會裡有人在會頻發言的時候
B 會將該訊息用密語自動複述給 A (包括會員名稱)
然後當 A 用密語發送訊息給 B 的時候 (例如訊息以 公會: 為開頭的訊息)
B 就會自動在會頻發出這段訊息

未知巨集能實現出來嗎?
如果能夠的話
能夠提供一下巨集嗎??

建議A回覆B時用組隊頻道比較不會跟密B的人搞混(以下格式也可以自行更改
隊頻回覆密語格式(不含[]符號):回覆[密B的人]說[回覆內容]
隊頻回覆工會格式(不含[]符號):工會說[回覆內容]
巨集大概如下,試試
#密語回報
automacro pm1 {
        pm /(.*)/
        exclusive 1
        run-once 1
        call {
        do pm "A的名子" $.lastpm 說 $.lastpmMsg
        release pm1
        }
}
automacro pm2 {
        party /回覆(.*)說(.*)/
        exclusive 1
        run-once 1
        call {
        do pm "$.lastMatch1" $.lastMatch2
        release pm2
        }
}

#工會回報
automacro guild1 {
        guild /(.*)/
        exclusive 1
        run-once 1
        call {
        do pm "A的名子" $.lastguild 說 $.lastguildMsg
        release guild1
        }
}
automacro guild2 {
        party /工會說(.*)/
        exclusive 1
        run-once 1
        call {
        do g $.lastMatch1
        release guild2
        }
}

但是....
當 B 是商人系在露天營業時
A 與 C 組隊均分中
又與 B 的等級相差有15等以上
若然要為了這巨集不均分的話不就本末倒至!?

什麼時候又蹦出一個C了
那試試以下吧,A可以用密語回覆B了
#密語回報
automacro pm1 {
        priority 2
        pm /(.*)/
        exclusive 1
        run-once 1
        call {
        do pm "A的名子" $.lastpm 說 $.lastpmMsg
        release pm1
        }
}
automacro pm2 {
        priority 1
        console /回覆(.*)說(.*)/
        exclusive 1
        run-once 1
        call {
        do pm "$.lastMatch1" $.lastMatch2
        release pm2
        }
}

#工會回報
automacro guild1 {
        guild /(.*)/
        exclusive 1
        run-once 1
        call {
        do pm "A的名子" $.lastguild 說 $.lastguildMsg
        release guild1
        }
}
automacro guild2 {
        priority 1
        console /工會說(.*)/
        exclusive 1
        run-once 1
        call {
        do g $.lastMatch1
        release guild2
        }
}

謝謝大大
我使用時是不是都是 回覆[密B的人]說[回覆內容] 與 工會說[回覆內容] ?

我不懂巨集
但是又想去了解其中運算過程
大大能說明一下中間那幾項指令是啥麼嗎???
另外 $.lastMatch 之類的有時是1又有時是2
這是怎樣來的??

沒錯,不過你也可以自行更改格式

我加上註解你在看看
#密語回報
automacro pm1 {
        priority 2
        #優先檢查觸發條件開關,數字越小越優先檢查
        pm /(.*)/
        #當以密語條件觸發時,$.lastpm(密語人物名稱)與$.lastpmMsg(密語內容)會被設定
        exclusive 1
        #不被其他自動巨集中斷開關
        run-once 1
        #只執行一次開關
        call {
        do pm "A的名子" $.lastpm 說 $.lastpmMsg
        #do是巨集指令,用來執行輸入外掛指令的動作
        #pm是外掛指令,指對某人發出密語
        release pm1
        #解除只觸發一次或是被鎖住的自動巨集
        }
}
automacro pm2 {
        priority 1
        #優先檢查觸發條件開關,數字越小越優先檢查
        console /回覆(.*)說(.*)/
        #以外掛視窗顯示的內容為條件觸發,(.*)表示任意字元
        exclusive 1
        #不被其他自動巨集中斷開關
        run-once 1
        #只執行一次開關
        call {
        do pm "$.lastMatch1" $.lastMatch2
        #$.lastMatch指的是符合常規表示式條件內容,
        #紅字為第一個符合條件所以是$.lastMatch1
        #黃字為第二個符合條件所以是$.lastMatch2
        release pm2
        #解除只觸發一次或是被鎖住的自動巨集
        }
}

#工會回報
automacro guild1 {
        guild /(.*)/
        #當以工會頻道為條件觸發,$.lastguild(工會人物名稱)與$.lastguildMsg(工會內容)會被設定
        exclusive 1
        #不被其他自動巨集中斷開關
        run-once 1
        #只執行一次開關
        call {
        do pm "A的名子" $.lastguild 說 $.lastguildMsg
        #do是巨集指令,用來執行輸入外掛指令的動作
        #pm是外掛指令,指對某人發出密語
        release guild1
        #解除只觸發一次或是被鎖住的自動巨集
        }
}
automacro guild2 {
        priority 1
        #優先檢查觸發條件開關,數字越小越優先檢查
        console /工會說(.*)/
        #以外掛視窗顯示的內容為條件觸發,(.*)表示任意字元
        #$.lastMatch指的是符合常規表示式條件內容
        #紅字為第一個符合條件所以是$.lastMatch1
        exclusive 1
        #不被其他自動巨集中斷開關
        run-once 1
        #只執行一次開關
        call {
        do g $.lastMatch1
        #do是巨集指令,用來執行輸入外掛指令的動作
        #g是外掛指令,指在工會頻道發言
        release guild2
        #解除只觸發一次或是被鎖住的自動巨集
        }
}

其餘你可以參考
日誌>>擴充巨集功能套件裡頭的巨集說明網頁
http://u.wgun.net/space.php?uid=1561059

喔~
這樣就容易了解個中運算方式了....
謝謝大大!