鍊金做水外掛 (已解決)

不知道有沒有人願意拿出來分享...
因為我今天在我水的地方看到有戀金外掛在做水
結果我就密她!!(一開始沒回 後來回了
他就問說怎 (旁邊有牧師 所以我慢慢插入話題
然後就問他可不可以給 鍊金的做水外掛..
他說........-..-
商業機密不外洩...
不知道這邊有沒有人願意
分享練金做水的 ""巨集""
(做水應該是用巨集.....)
麻煩了!!
因為爬帖都爬不到...
我又是要自己做芭樂的==~

這是以前找到的製作酒精巨集,妳試試
提領npc座標跟提領數量請自行調整
# 製作酒精
automacro pharmacy {
        sp > 20
        inventory "酒精製作說明書" == 1
        inventory "藥缽" >= 1
        inventory "空瓶" >= 1
        inventory "空試管" >= 1
        inventory "植物梗" >= 5
        inventory "毒魔菇芽孢" >= 5
        exclusive 1
        run-once 1
        call {
                do ss 228 10
                do send 8E 01 CA 03 00 00 00 00 00 00
                release pharmacy
        }
}
# 補貨判斷
automacro check {
        inventory "藥缽" == 0
        inventory "空瓶" == 0
        inventory "空試管" == 0
        inventory "植物梗" < 5
        inventory "毒魔菇芽孢" < 5
        run-once 1
        call storage
}

macro storage {
        lock pharmacy
        pause 1
        do talk @npc (XX YY) <--把XX跟YY改成你要領取的NPC座標
        pause 1
        do talk cont
        do talk resp 1
        pause 1
        # 若身上有上次做出來的成品，則存入倉庫
        if (@invamount(酒精) == 0) goto jump
        do storage add @inventory(酒精) @invamount(酒精)
        :jump
        # 由倉庫取出材料
        do storage get @storage (空瓶) 60
        do storage get @storage (藥缽) 60
        do storage get @storage (空試管) 60
        do storage get @storage (植物梗) 300
        do storage get @storage (毒魔菇芽孢) 300
        pause 1
        do storage close
        release check
        release pharmacy
        pause 1
}

如果要做其他藥水,方式跟上面一樣
只要把材料跟封包改掉就可以了
其他藥水的封包如下
#紅色藥水 = 8E 01 F5 01 00 00 00 00 00 00
#黃色藥水 = 8E 01 F7 01 00 00 00 00 00 00
#白色藥水 = 8E 01 F8 01 00 00 00 00 00 00
#藍色藥水 = 8E 01 F9 01 00 00 00 00 00 00
#曼特療傷藥 = 8E 01 5D 02 00 00 00 00 00 00
#蘆薈汁液 8E 01 5E 02 00 00 00 00 00 00
#紅色纖細藥水 = 8E 01 21 02 00 00 00 00 00 00
#黃色纖細藥水 = 8E 01 22 02 00 00 00 00 00 00
#白色纖細藥水 = 8E 01 23 02 00 00 00 00 00 00
#酒精 = 8E 01 CA 03 00 00 00 00 00 00
#火煙瓶 = 8E 01 DF 1B 00 00 00 00 00 00
#強酸瓶 = 8E 01 E0 1B 00 00 00 00 00 00
#噬人植物瓶 = 8E 01 E1 1B 00 00 00 00 00 00
#刺錘瓶 = 8E 01 E2 1B 00 00 00 00 00 00
#護貝藥 = 8E 01 E3 1B 00 00 00 00 00 00

挖@@
超謝謝你了><
是說我今天才花一整個下午==
中午約11點多開始
做到剛剛7點半==+
把我目前部分的材料做了一下==....
但超謝謝你的Q口Q

呵 小弟最近也打算做水 剛好看到有大大PO文 拿來研究一下
有巨集真的方便多了(還再努力學習><) 感謝樓上的大大!!

我有多人物  很想學會寫巨集..這樣就可以開多隻人物施放計能做水了..
還得再加油=口=
有很多問題想問說ˊˋ..

哇  沒想到會有人提供出來
說明也可以理解
實在是太感謝大大了

超級感謝超級感謝超級感謝超級感謝超級感謝超級感謝

奇怪了!

X大您PO這個看起來簡單多了!

我找到那個看起來好複雜
(可能是作者太強了!寫的好"精采")


# 1. 倉庫備妥至少藥缽150個、空瓶150個、空試管150個、植物梗750個、毒魔菇芽孢750個
# 2. 把酒精製作說明書帶在身上
# 3. 決定存倉用卡普拉NPC的座標，並將座標填入初始變數 $npcLocation 後面
# 4. 移動至看得到卡普拉NPC的任何一點上
# 5. 身上物品儘量清空
# 6. 組隊
# 7. 執行程式，待出現"設定值初始化完畢"訊息後鍵入指令 "macro start"

# 設定值初始化
automacro initiate {
        run-once 1
        call {
                # 以下設定卡普拉所在座標，可根據不同的卡普拉 NPC 座標作更改
                $npcLocation = 327 108
                # 其他想要初始化設定什麼的可以在下面新增
                do conf storageAuto 0
                do conf sellAuto 0
                do conf autoTalkCont 0
                do conf logPartyChat 1
                do conf sitAuto_sp_lower 0
                do conf sitAuto_sp_upper 0
                do conf sitAuto_over_50 0
                # 一組材料重 14
                do eval $::Macro::Data::varStack{controlAmount} = int(($::char->{'weight_max'} * 0.5 - $::char->{'weight'}) / 14)
                # $controlAmount = @eval(int(($.maxweight * 0.5 - $.weight) / 14))
                log 最大可攜帶 $controlAmount 組材料而不負重
                if ($controlAmount > 0) goto jump1
                        log ***** 注意！未攜帶材料前已負重，可能導致巨集執行錯誤！ *****
                :jump1
                if (@invamount(酒精製作說明書) != 0) goto jump2
                        log ***** 注意！酒精製作說明書尚未帶在身上 *****
                :jump2
                log 設定值初始化完畢
        }
}
# 補貨判斷
automacro refillCheck {
        sp > 95%
        inventory "酒精製作說明書" == 1
        inventory "藥缽" = 0
        inventory "空瓶" >= 0
        inventory "空試管" >= 0
        inventory "植物梗" >= 0
        inventory "毒魔菇芽孢" >= 0
        # 以下為倉庫物品存量判斷
        var medicineBowls > 150
        var emptyBottles > 150
        var emptyTestTubes > 150
        var stems > 750
        var poisonSpores > 750
        run-once 1
        call start
}
# 補貨
macro start {
        lock pharmacy
        pause 1
        do talk @npc ($npcLocation)
        do talk cont
        do talk resp 1
        pause 2
        # 若身上有上次做出來的酒精，則存入倉庫
        if (@invamount(酒精) == 0) goto jump
                $usedMedicineBowls = @eval($tempMedicineBowls - @invamount(藥缽))
                $finishedAmount = @invamount(酒精)
                do storage add @inventory(酒精) @invamount(酒精)
        # 本 if 為計算成功率用
        if ($usedMedicineBowls <= 0) goto jump
                $rateOfSuccess = @eval($finishedAmount / $usedMedicineBowls)
                do eval $::Macro::Data::varStack{rateOfSuccess} = sprintf("%.2f",$::Macro::Data::varStack{rateOfSuccess} * 100) . '%';
                do p 上批製造 $usedMedicineBowls 個酒精成功率 $rateOfSuccess
        :jump
        # 由倉庫取出材料
        do storage get @storage(藥缽) @eval(150 - @invamount(藥缽))
        do storage get @storage(空瓶) @eval(150 - @invamount(空瓶))
        do storage get @storage(空試管) @eval(150 - @invamount(空試管))
        do storage get @storage(植物梗) @eval(750 - @invamount(植物梗))
        do storage get @storage(毒魔菇芽孢) @eval(750 - @invamount(毒魔菇芽孢))
        [
        $medicineBowls = @storamount(藥缽)
        $emptyBottles = @storamount(空瓶)
        $emptyTestTubes = @storamount(空試管)
        $stems = @storamount(植物梗)
        $poisonSpores = @storamount(毒魔菇芽孢)
        $tempMedicineBowls = @invamount(藥缽)
        ]
        # 由隊頻顯示並記錄倉庫材料剩餘量與成品數量
        do p 藥缽尚餘 $medicineBowls 個
        do p 空瓶尚餘 $emptyBottles 個
        do p 空試管尚餘 $emptyTestTubes 個
        do p 植物梗尚餘 $stems 個
        do p 毒魔菇芽孢尚餘 $poisonSpores 個
        do p 酒精庫存 @storamount(酒精) 個
        pause 1
        do storage close
        release refillCheck
        release pharmacy
}
# 製藥判斷
automacro pharmacy {
        sp > 20
        inventory "酒精製作說明書" == 1
        inventory "藥缽" >= 1
        inventory "空瓶" >= 1
        inventory "空試管" >= 1
        inventory "植物梗" >= 5
        inventory "毒魔菇芽孢" >= 5
        exclusive 1
        run-once 1
        call {
                do ss 228 10
                do send 8E 01 CA 03 00 00 00 00 00 00
                release pharmacy
        }

實在是太感謝大大了

實在是太感謝大大了

實在是太感謝大大了,謝謝樓主的分享~~~

大大您好!請問如果我想改成座曾大水
那code該如何更改
或者要選第一個選項來確認技能
該如何做調整

謝謝