補師跟隨打手練功 如何使用巨集 傳送回村和到練功地圖?

請巨集高手幫幫忙
要如何使用傳送之陣 把打手跟補師傳到練功地圖 和 回村存取

有高手可以幫幫忙嗎  我會很感激妳的

大概方式如下,妳試試吧
補師:
automacro pm1 {
        pm /回城/
        player "打手的名子", 10
        inventory "藍色魔力礦石" > 0
        overrideAI 1
        exclusive 1
        run-once 1
        call home
}
macro home {
        $z = @invamount(藍色魔力礦石)
        $x = @arg("$.pos", 1)
        $y = @arg("$.pos", 2)
        $x0 = @eval($x - @random("1", "-1"))
        $y0 = @eval($y - @random("1", "-1"))
        do sl 27 $x0 $y0
        pause 1
        do warp 地圖名稱
        #儲存地圖
        pause 1
        if ($z = @invamount(藍色魔力礦石)) goto retry
        do pm "打手的名子" move $x0 $y0
        pause 5
        do move $x0 $y0
        pause 2
        release pm1
        stop
        :retry
        call home
}
automacro pm2 {
        pm /出發/
        player "打手的名子", 10
        inventory "藍色魔力礦石" > 0
        overrideAI 1
        exclusive 1
        run-once 1
        call go
}
macro go {
        $z = @invamount(藍色魔力礦石)
        $x = @arg("$.pos", 1)
        $y = @arg("$.pos", 2)
        $x0 = @eval($x - @random("1", "-1"))
        $y0 = @eval($y - @random("1", "-1"))
        do sl 27 $x0 $y0
        pause 1
        do warp 地圖名稱
        #鎖定地圖
        pause 1
        if ($z = @invamount(藍色魔力礦石)) goto retry
        do pm "打手的名子" move $x0 $y0
        pause 5
        do move $x0 $y0
        pause 2
        release pm2
        stop
        :retry
        call go
}


打手:
automacro home {
        console /自動存倉/
        player "補師的名子", 10
        overrideAI 1
        exclusive 1
        run-once 1
        call {
        do conf route_randomWalk 0
        do reload config
        pause 1
        do pm "補師的名子" 回城
        release home
        }
}
automacro go {
        console /倉庫已關閉./
        player "補師的名子", 10
        overrideAI 1
        exclusive 1
        run-once 1
        call {
        do conf route_randomWalk 0
        do reload config
        pause 1
        do pm "補師的名子" 出發
        release go
        }
}
automacro pm {
        pm /move (.*) (.*)/
        player "補師的名子", 10
        overrideAI 1
        exclusive 1
        run-once 1
        call {
        pause 1
        do move $.lastMatch1 $.lastMatch2
        pause 2
        do conf route_randomWalk 2
        do reload config
        release pm
        }
}