傳送巨集~被亂求救!!!!!

最近一到假日~
就會被一些小初們點交易
很明顯是來亂的
不知道有沒有辦法可以拒絕或者是解決這樣的辦法
不然這樣我都不用做生意了啦TAT

automacro Start {
        console /Your Coordinates/
        exclusive 1
        call {
        pause 3
        do conf ignoreAll 1
        call Chat
        }
}
macro Chat {
        do sit
        do look 4
        if (@invamount(藍色魔力礦石) > 0) goto OK
                do chat create "石頭沒了○o○" 2 0 9527
                stop
        :OK
                do chat create "朱諾2900古城3000石波3200炎波3300" 2 0 9527
# 自行修改聊天室內容
                do deal no
# 避免在使用傳陣到創聊天室之間有人點交易
}
automacro Deala {
        console /Requests a Deal/
        inventory "藍色魔力礦石" > 0
        call {
        do deal
        pause 15
        do deal no
        }
}
automacro Dealb {
        console /added Item to Deal/
        call {
        do deal no
        }
}
automacro Dealc {
        console /added (.*) z to Deal/
        call {
        $a = $.lastMatch1
        if ($a = 2,900) goto OK
        if ($a = 3,200) goto OK
        if ($a = 3,000) goto OK
        if ($a = 3,300) goto OK
# 自行修改金額
                do deal no
                stop
        :OK
                pause 1
                do deal
                pause 1
                do deal
                pause 10
                do deal no

        }
}
automacro Warp {
        console /You gained (.*) zeny/
        exclusive 1
        call {
        $b = @invamount(藍色魔力礦石)
        do chat leave
        :Top
        $x = @arg("$.pos", 1)
        $y = @arg("$.pos", 2)
        $x0 = @eval($x - @rand(1,3))
        $y0 = @eval($y - @rand(1,3))
                do sl 27 $x0 $y0
                pause 2
        if ($a == "2,900") goto A
        if ($a == "3,200") goto B
        if ($a == "3,000") goto C
        if ($a == "3,300") goto D
# 傳送點一
        :A
                do warp yuno
# 傳送點二
                goto End
        :B
                do warp ve_fild07
# 傳送點三
                goto End
        :C
                do warp glast_01
# 傳送點四

        :D
               do warp ve_fild03
                goto End
        :End
                pause 3
        if ($b == @invamount(藍色魔力礦石)) goto Top
# 使用傳陣藍礦未減少回到Top
                do c 你的地圖已開
                call Chat
        }
}


以上是我的巨集~
不知道有沒有達人可以告訴我怎麼改

加個觸發條件run-once試試
run-once (0|1)
當設為 1 時該自動巨集會在觸發後失效（只觸發一次，之後便不再觸發）。
不過需要搭配巨集指令release使該自動巨集重新恢復。

不好意思...本人巨集學的不是很好~
所以想請X大大可不可以再明確的告訴我要怎麼做調整嗎...

我修改了一下再加一個取消交易觸發的巨集,你試試
automacro Start {
        console /Your Coordinates/
        exclusive 1
        call {
        pause 3
        do conf ignoreAll 1
        call Chat
        }
}
macro Chat {
        do sit
        do look 4
        if (@invamount(藍色魔力礦石) > 0) goto OK
        do chat create "石頭沒了○o○" 2 0 9527
        stop
        :OK
        do chat create "朱諾2900古城3000石波3200炎波3300" 2 0 9527
        # 自行修改聊天室內容
        do deal no
        # 避免在使用傳陣到創聊天室之間有人點交易
        release Deala
}
automacro Deala {
        console /Requests a Deal/
        inventory "藍色魔力礦石" > 0
        run-once 1
        call {
        do deal
        pause 15
        do deal no
        }
}
automacro Dealb {
        console /added Item to Deal/
        call {
        do deal no
        }
}
automacro Dealc {
        console /added (.*) z to Deal/
        call {
        $a = $.lastMatch1
        if ($a = 2,900) goto OK
        if ($a = 3,200) goto OK
        if ($a = 3,000) goto OK
        if ($a = 3,300) goto OK
        # 自行修改金額
        do deal no
        stop
        :OK
        pause 1
        do deal
        pause 1
        do deal
        pause 10
        do deal no
        }
}
automacro Warp {
        console /You gained (.*) zeny/
        exclusive 1
        call {
        $b = @invamount(藍色魔力礦石)
        do chat leave
        :Top
        $x = @arg("$.pos", 1)
        $y = @arg("$.pos", 2)
        $x0 = @eval($x - @rand(1,3))
        $y0 = @eval($y - @rand(1,3))
        do sl 27 $x0 $y0
        pause 2
        if ($a == "2,900") goto A
        if ($a == "3,200") goto B
        if ($a == "3,000") goto C
        if ($a == "3,300") goto D
        # 傳送點一
        :A
        do warp yuno
        goto End
        # 傳送點二
        :B
        do warp ve_fild07
        goto End
        # 傳送點三
        :C
        do warp glast_01
        goto End
        # 傳送點四
        :D
        do warp ve_fild03
        goto End
        :End
        pause 3
        if ($b == @invamount(藍色魔力礦石)) goto Top
        # 使用傳陣藍礦未減少回到Top
        do c 你的地圖已開
        call Chat
        }
}
automacro Dealno {
        console /交易已取消|Deal Cancelled/
        call {
        release Deala
        }
}